# How to use random-number generators in SAS

January 29, 2018
By

 This post was kindly contributed by The DO Loop - go there to comment and to read the full post.

What is a random number generator? What are the random-number generators in SAS, and how can you use them to generate random numbers from probability distributions? In SAS 9.4M5,
you can use the STREAMINIT function to select from eight random-number generators (RNGs), including five new RNGs. After choosing an RNG, you can use the RAND function to obtain random values from probability distributions.

### What is a random-number generator?

A random-number generator usually refers to a deterministic algorithm that generates uniformly distributed random numbers.
The algorithm (sometimes called a pseudorandom-number generator, or PRNG) is initialized by an integer, called the seed, which sets the initial
state of the PRNG. Each iteration of the algorithm produces a pseudorandom number and advances the internal state. The seed completely determines the sequence of random numbers. Although it is deterministic, a modern PRNG generates
extremely long sequences of numbers whose statistical properties are virtually indistinguishable from a truly random uniform process.

An RNG can also refer to a hardware-based device (sometimes called a “truly random RNG”) that
samples from an entropy source, which is often thermal noise within the silicon of a computer chip. In the Intel implementation, the random
entropy source is used to initialize a PRNG in the chip, which generates a short stream of pseudorandom values
before resampling from the entropy source and repeating the process. A hardware-based RNG is not deterministic or reproducible.

An RNG generates uniformly distributed numbers. If you request random numbers from a nonuniform probability distribution (such as the normal or exponential distributions), SAS will automatically apply mathematical transformations that convert the uniform numbers into nonuniform random variates.

### Using random numbers in the real world

In the real world, random numbers are used as the basis for statistical simulations. Financial analysts use simulations of the economy to evaluate the risk of a portfolio. Insurance companies use simulations of natural disasters to assess the impact on their customers. Government workers use simulations of population growth to predict the infrastructure and services that will be required by future generations. In all fields, data analysts generate random
values for statistical sampling, bootstrap and resampling
methods, Monte Carlo estimation, and data simulation.

For these techniques to be statistically valid, the values that
are produced by statistical software must contain a high degree of randomness. The new random-number generators in SAS provide analysts with fast, high-quality, state-of-the-art random numbers.

### New random-number generators in SAS

Prior to SAS 9.4M5, SAS supported the Mersenne twister random-number generator (introduced in SAS 9.1) and a hardware-based RNG (supported on Intel CPUs in SAS 9.4M3). SAS 9.4M5 introduces new random-number generators and new variants of the Mersenne twister, as follows:

• PCG:
A 64-bit permuted congruential generator (O’Neill 2014) with good statistical properties.
• TF2:
A 2×64-bit counter-based RNG that is based on the Threefish encryption function in the Random123
library (Salmon et al. 2011). The generator is also known as the 2×64 Threefry generator.
• TF4:
A 4×64-bit counter-based RNG that is also known as the 4×64 Threefry generator.
• RDRAND:
A hardware-based RNG (Intel, 2014) that is repeatedly reseeded by using random values from thermal noise in the chip. The RNG requires an Intel processor (Ivy Bridge and later) that supports the RDRAND
instruction.
• MT1998: (deprecated)
The original 1998 32-bit Mersenne twister algorithm (Matsumoto and Nishimura, 1998). This was the default RNG for the RAND function prior to SAS 9.4M3. For a small number of seed values (those
exactly divisible by 8,192), this RNG does not produce a sufficiently random stream of numbers.
Consequently, other RNGS are preferable.
• MTHYBRID: (default)
A hybrid method that improves the MT1998 method by using the MT2002 initialization for seeds that
are exactly divisible by 8,192. This is the default RNG, beginning with the SAS 9.4M3.
• MT2002:
The 2002 32-bit Mersenne twister algorithm (Matsumoto and Nishimura 2002).
• MT64:
A 64-bit version of the 2002 Mersenne twister algorithm.

### Choose a random-number generator in SAS

In SAS, you can use the STREAMINIT subroutine to choose an RNG and to set the seed value.
You can then use the RAND function to
produce high-quality streams of random numbers for many common distributions. The first argument to the RAND
function specifies the name of the distribution. Subsequent arguments specify parameters for the distribution.

If you want to use the default RNG (which is ‘MTHYBRID’), you can specify only the seed.
For example, the following DATA step initializes the default PRNG with the seed value 12345 and then generates five observations from the uniform distribution on (0,1) and from the standard normal distribution:

``` data RandMT(drop=i); call streaminit(12345); /* choose default RNG (MTHYBRID) and seed=12345 */ do i = 1 to 5; uMT = rand('Uniform'); /* generate random uniform: U ~ U(0,1) */ nMT = rand('Normal'); /* generate random normal: N ~ N(mu=0, sigma=1) */ output; end; run; ```

If you want to choose a different RNG, you can specify the name of the RNG followed by the seed.
For example, the following DATA step initializes the PCG method with the seed value 12345 and then generates five observations from the uniform and normal distributions:

``` data RandPCG(drop=i); call streaminit('PCG', 12345); /* SAS 9.4M5: choose PCG method, same seed */ do i = 1 to 5; uPCG = rand('Uniform'); nPCG = rand('Normal'); output; end; run; ```

A hardware-based method is initialized by the entropy source, so you do not need to specify a seed value.
For example, the following DATA step initializes the RDRAND method and then generates five observations. The three data sets are then merged and printed:

```   data RandHardware(drop=i); call streaminit('RDRAND'); /* SAS 9.4M3: Hardware method, no seed */ do i = 1 to 5; uHardware = rand('Uniform'); nHardware = rand('Normal'); output; end; run;   data All; merge RandMT RandPCG RandHardware; run;   title "Uniform Random Variates for Three RNGs"; proc print data=All noobs; var u:; run;   title "Normal Random Variates for Three RNGs"; proc print data=All noobs; var n:; run; ```

The output shows that each RNG generates a different sequence of numbers. If you run this program yourself, you will generate the same sequences for the first two columns (the MTHYBRID and PCG streams), but your numbers for the RDRAND RNG will be different. Each column of the first table is an independent random sample from the uniform distribution. Similarly, each column of the second table is an independent random sample from the standard normal distribution.

### Summary

In SAS 9.4M5, you can choose from eight different random-number generators. You use the STREAMINIT function to select the RNG and use the RAND function to obtain random values.
In a future blog post, I will compare the attributes of the different RNGs and discuss the advantages of each. I will also show how to use the new random-number generators to generate random numbers in parallel by running a DS2 program in multiple threads.

The information in this article is taken from my forthcoming SAS Global Forum 2018 paper, “Tips and Techniques for Using the Random-Number Generators in SAS” (Sarle and Wicklin, 2018).

### References

The post How to use random-number generators in SAS appeared first on The DO Loop.

 This post was kindly contributed by The DO Loop - go there to comment and to read the full post.

Tags: , ,

## Welcome!

SAS-X.com offers news and tutorials about the various SAS® software packages, contributed by bloggers. You are welcome to subscribe to e-mail updates, or add your SAS-blog to the site.