Through the years: SAS Enterprise Guide versions

Last week Rick Wicklin posted a nifty chart that shows the timeline of SAS releases since Version 8. A few of you asked if I could post a similar chart for SAS Enterprise Guide. Here it is. Like Rick, I used new features in SAS 9.4 to produce this chart (in fact, I cribbed heavily from his code)…but I used SAS Enterprise Guide 6.1 to run the program.

You might notice that my chart is a bit busier than Rick’s version. As a desktop client application that works across multiple SAS versions, we tend to issue major releases of SAS Enterprise Guide more often than we update the core engine of SAS software.

On my chart, the labels on the data points indicate the “event” that motivated the release. In some cases, we issued a new release to go with a new version of SAS (such as v1.2 with SAS 8.2). In other cases, we “remastered” a version to support more languages or another operating system (such as Microsoft Vista support with v4.1 in 2007, or the L10N release of v4.3 in 2010).

You might also notice that some of these releases happened very close together. Often, SAS R&D works on updates to multiple releases in parallel. Developers make changes to multiple versions to provide maintenance and hotfix changes (based on customer needs), while still contributing to the Next Big Version that will contain the compelling new features (based on customer wishes).

Here’s the code that produced the chart:

data Releases;
	format Date DATE7.;
	input Category $8. Release $7. Date DATE9. Details $15.;
	datalines;
Ancient 1.0    01Nov1999 SAS 8.0
Ancient 1.1    01Jul2000 SAS 8.1
Ancient 1.2    01Apr2001 SAS 8.2
Ancient 1.3    01Sep2001 
Ancient 2.0    01Sep2002 
Ancient 2.05   01May2003 SAS 9.0
Ancient 2.1    01Apr2004 SAS 9.1
Ancient 3.0    01May2004 .NET rewrite
Ancient 3.02   01Feb2005 remaster/L10N
Old     4.1    01Mar2006 
Old     4.1v   01Apr2007 Vista
Old     4.2    01Mar2009 SAS 9.2
Old     4.22   01Sep2009 SAS 9.2m2
Recent  4.3    01Aug2010
Recent  4.305l 01Sep2010 L10N
Recent  4.305r 01Jul2011 SAS 9.3
Recent  5.1    01Feb2012
Recent  6.1    01Jul2013 SAS 9.4
;
 
/* running in SAS EG - modify active ODS to add title to graph */
ods tagsets.sasreport13(id=egsr) gtitle;
 
ods graphics / height=800 width=1000;
title "SAS Enterprise Guide Releases";
proc sgplot data=Releases noautolegend;
	styleattrs datacolors=(red yellow green);
	block x=date block=category / transparency = 0.85;
	scatter x=date y=release / datalabel=Details 
		datalabelpos=right 
		datalabelattrs=(size=10pt)
		markerattrs=(symbol=CircleFilled size=14);
	xaxis grid type=time offsetmax=0.1 offsetmin=0;
	yaxis type=discrete grid offsetmax=0.1 label="Release/Event";
run;